Method code for $directories.find_page__objref()

[Turn on line numbering]

---

arg url, interface;
var page, script_name, meth, found, lock, obj;

script_name = "";
if ((| (obj = $object_lib.to_dbref(url[1])) |)) {
    page = obj;
    script_name += "/" + url[1];
    url = url.subrange(2);
    if ((| (meth = tosym(url[1])) |)) {
        if ((| page.find_method(meth) |)) {
            interface.set_info('generate, meth);
            script_name += "/" + url[1];
            url = url.subrange(2);
            found = 1;
            if (page.has_ancestor($page) && page.get_lock())
                lock = page;
        } else {
            return 'pagenf;
        }
    } else if ((| page.find_method('generate) |)) {
        interface.set_info('generate, 'generate);
        script_name;
        found = 1;
        if (page.has_ancestor($page) && page.get_lock())
            lock = page;
    } else {
        return 'pagenf;
    }
    interface.set_info('script_name, script_name);
    interface.set_info('path_info, "/" + url.join("/"));
    interface.set_info('directory_object, $directories);
    interface.set_info('lock_object, lock);
    return page;
}
return 'pagenf;

---

// Brad Roberts
// Bruce Mitchener, Jr.
// Created 16-May-1997 as a part of ColdCore, see: @help Credit